; ===============================================================================================
; Wrye Bash Installation Wizard for SkyFalls and SkyMills v3.3.1
; ===============================================================================================
;
; Version: 3.3
; Author: SjoertJansen
; Date: 04 February 2014
;
; Configuration Settings
; ======================
;
sImages = "-- Images"						; Folder containing images
sCoreNum = "01"								; Core Sub-Package number
sModNum = "02"								; Falskaar or Wyrmstooth sub-package number
sSkySubPackage = " SkyFalls + SkyMills"		; Base sub-package prefix (leading space required)
sCoreDLC = "03 Basic Core files DB + DG Only"	; Required if Dragonborn and/or Dawnguard is present with or without
												; Falskaar and/or Wyrmstooth installed, but not all of them.
sSkyrimLOD = "11 LOD "						; LOD mod compatibility prefix
sWindmillSize = "21 Windmill "				; Windmill size sub-package prefix (trailing space required)
sWaterfalls = "22 Waterfalls "				; Waterfalls sub-package prefix (trailing space required)
sSmallFalls = "31 Small Waterfalls"			; Small Waterfalls options
sParallaxPatch = "41 Parallax Patch"		; Parallax Patch sub-package
; ________________________________________________________________________________________________

If CompareWBVersion(292) < 0
    Cancel "Для запуска мастера требуется Wrye Bash v292 или выше"
EndIf

DeSelectAll
 
; Initialise mod presence variables
sDB = ""	; Dragonborn
sDG = ""	; Dawnguard
sFS = ""	; Falskaar
sWT = ""	; Wyrmstooth

iModCount = 0	; Number of mods installed
 
; Detect which mods are present on the system
If DataFileExists("Dragonborn.esm")
	sDB = " + DB"
	iModCount += 1
EndIf
If DataFileExists("Dawnguard.esm")
	sDG = " + DG"
	iModCount += 1
EndIf
If DataFileExists("Falskaar.esm")
	sFS = " + FS"
	iModCount += 1
EndIf
If DataFileExists("Wyrmstooth.esp")
	sWT = " + WT"
	iModCount += 1
EndIf

; Select required SkyFalls and SkyMills sub-packages
If iModCount == 4
	SelectSubPackage sCoreNum + sSkySubPackage + sDG + sDB + sFS + sWT
Else
	SelectSubPackage sCoreNum + sSkySubPackage + sDG + sDB
	If len(sDG + sDB) > 0
			SelectSubPackage sCoreDLC
		If len(sFS + sWT) > 0
				SelectSubPackage sModNum + sSkySubPackage + sFS + sWT
		EndIf
	EndIf
EndIf

; Select Parallax Patch if required
If DataFileExists("EpisodeParallax.esp")
	SelectSubPackage sParallaxPatch
EndIf

; Display available options
SelectOne "Используете ли вы SDO или Expand Object LODs?", \
	"|Я использую SDO", "Выберите эту опцию при наличии мода Skyrim Distance LOD Overhaul.", "", \
	"Я использую Expand Object LODs", "Выберите эту опцию при наличии мода The Expand Object LODs", "", \
	"Нет", "Выберите эту опцию, если вы не используете моды Skyrim Distance LOD Overhaul и/или Expanded Object LODs", ""
	
	Case "Я использую SDO"
		SelectSubPackage sSkyrimLOD + "Grieche patch"
	Break
	Case "Я использую Expand Object LODs"
		SelectSubPackage sSkyrimLOD + "tamu75 patch"
	Break
	Case "Нет"
		SelectSubPackage sSkyrimLOD + "Skyrim LOD"
	Break
EndSelect

SelectOne "Размер лопастей мельниц", \
	"|1.5x больше (рекомендуется)", "Выберите эту опцию, если хотите, чтобы мельницы действительно выглядели как мельницы!\n\n## Благодарю Pfaffendrill за позволение использовать модели из его мода, пожалуйста, поставьте ему Endorse: http://www.nexusmods.com/skyrim/mods/30026/ ##", sImages + "/1.5x Mill.bmp", \
	"1.25x больше", "Выберите эту опцию, если хотите, чтобы лопасти мельниц были только немного больше, чем в оригинальной игре (зачем вам это?).\n\n## Благодарю Pfaffendrill за позволение использовать модели из его мода, пожалуйста, поставьте ему Endorse: http://www.nexusmods.com/skyrim/mods/30026/ ##", sImages + "/1.25x Mill.bmp", \
	"Как в оригинальной игре", "Выберите эту опцию, если хотите, чтобы размер мельниц остался прежним.\n\nСерьезно? Вы вообще мельницу видели?", sImages + "/Vanilla Mill.bmp"
	
	Case "1.5x больше (рекомендуется)"
		SelectSubPackage sWindmillSize + "1.5x"
	Break
	Case "1.25x больше"
		SelectSubPackage sWindmillSize + "1.25x"
	Break
	Case "Как в оригинальной игре"
		SelectSubPackage sWindmillSize + "Vanilla"
	Break
EndSelect

SelectOne "Модели водопадов", \
	"|Realistic Water Two", "Выберите эту опцию, если хотите использовать модели из Realistic Water Two от Isoku.\n\nМожет использоваться с любым модом, изменяющим поверхности воды, ваш выбор не привяжет вас ни к какому конкретному моду!\n\n## Благодарю Isoku за позволение использовать модели из его мода, пожалуйста, поставьте ему Endorse: http://www.nexusmods.com/skyrim/mods/41076/ ##", sImages + "/Realistic Water 2.bmp", \
	"W.A.T.E.R.", "Выберите эту опцию, если хотите использовать модели из W.A.T.E.R. от SparrowPrince.\n\nМожет использоваться с любым модом, изменяющим поверхности воды, ваш выбор не привяжет вас ни к какому конкретному моду!\n\n## Благодарю SparrowPrince а позволение использовать модели из его мода, пожалуйста, поставьте ему Endorse: http://www.nexusmods.com/skyrim/mods/13268/ ##", sImages + "/W.A.T.E.R..bmp", \
	"Из оригинальной игры", "Выберите эту опцию, если вы хотите оставить оригинальные водопады.\n\nМожет использоваться с любым модом, изменяющим поверхности воды.", sImages + "/Vanilla.bmp"
	
	Case "Realistic Water Two"
		SelectSubPackage sWaterfalls + "Realistic water 2"
	Break
	Case "W.A.T.E.R."
		SelectSubPackage sWaterfalls + "W.A.T.E.R"
	Break
	Case "Из оригинальной игры"
		SelectSubPackage sWaterfalls + "Vanilla"
	Break
EndSelect

; Small Waterfalls options (only if DB or FS is installed)
If len(sDB + sFS) > 0
	sMessage = ""
	If len(sDB) > 0
		sMessage = "Dragonborn"
		If len(sFS) > 0
			sMessage = sMessage + " и Falskaar"
		EndIf
	Else
		sMessage = "Falskaar"
	EndIf
	SelectOne "Анимировать небольшие водопады и ручейки?", \
		"|Да", "Это опциональный ESP для " + sMessage + ", который делает небольшие водопады и ручейки анимированными при взгляде с дистанции.\n\nСлегка влияет на производительность.", "", \
		"Нет", "", ""
	
	Case "Да"
		SelectSubPackage sSmallFalls + sDB + sFS
	Break
EndIf

Return